2.22. Wat is het percentage uitstroom van niet-zorggerelateerd personeel in loondienst?

Concepten

• Arbeidsovereenkomst
• Functie in organisatie-rol
• Werkovereenkomst afspraak
• Zorgverlener (functie)

Relaties

• gaat over
• heeft deel
• heeft opdrachtnemer

Eigenschappen

• einddatum
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 2.22
2# Parameters: ?jaar
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-g:   <http://purl.org/ozo/onz-g#>
6PREFIX onz-pers:<http://purl.org/ozo/onz-pers#>
7PREFIX onz-org: <http://purl.org/ozo/onz-org#>
8PREFIX xsd:     <http://www.w3.org/2001/XMLSchema#>
9
10SELECT
11  ?Periode
12  ("Totaal organisatie" AS ?Indeling)
13  ?Aantal_PIL_zonder_zorgfunctie
14  ?Aantal_uitgestroomde_PIL_zonder_zorgfunctie
15  ?Procent_Uitstroom 
16WHERE {
17  {
18    SELECT
19      ?Periode
20      (SUM(?noemer_waarde) AS ?Aantal_PIL_zonder_zorgfunctie)
21      (SUM(?teller_waarde) AS ?Aantal_uitgestroomde_PIL_zonder_zorgfunctie)
22      (IF(SUM(?noemer_waarde) = 0,
23          "Ongedefinieerd",
24          ROUND( (100.0 * SUM(?teller_waarde) / SUM(?noemer_waarde)) * 100 ) / 100
25         ) AS ?Procent_Uitstroom)
26    WHERE {
27      {
28        SELECT
29          ?Periode
30          ?werknemer
31          (IF(MAX(?op_peildatum_eerder) = 1, 1, 0) AS ?noemer_waarde)
32          (IF(MAX(?op_peildatum_eerder) = 1 && MAX(?op_peildatum_later) = 0, 1, 0) AS ?teller_waarde)
33        WHERE {
34		      #BIND(2024 AS ?jaar)
35          VALUES ?kw { 1 2 3 4 0 }
36
37          # Eerste dag van het kwartaal
38 		  BIND( xsd:date(CONCAT(STR(?jaar), "-",
39                        IF(?kw=1,"01-01", IF(?kw=2,"04-01", IF(?kw=3,"07-01", IF(?kw=4,"10-01", "01-01"))))
40           )) AS ?p_start )
41
42          # Eerste dag van het opvolgende kwartaal (of volgend jaar bij ?kw = 0)
43          BIND(IF( ?kw = 0, xsd:date(CONCAT(STR(?jaar + 1), "-01-01")),?p_start + "P3M"^^xsd:duration) AS ?p_next)
44          BIND(IF(?kw = 0, "Totaal jaar", CONCAT("Q", STR(?kw))) AS ?Periode )
45
46          # ArbeidsOvereenkomst + afspraken zonder zorgverlenersfunctie
47          ?overeenkomst
48            a onz-pers:ArbeidsOvereenkomst ;
49            onz-pers:heeftOpdrachtnemer ?werknemer ;
50            onz-g:hasPart ?overeenkomst_afspraak .
51          ?overeenkomst_afspraak
52            a onz-pers:WerkOvereenkomstAfspraak ;
53            onz-g:isAbout ?functie ;
54            onz-g:startDatum ?start_afspraak .
55          OPTIONAL { ?overeenkomst_afspraak onz-g:eindDatum ?eind_afspraak . }
56
57          ?functie a onz-g:OccupationalPositionRole .
58          FILTER NOT EXISTS { ?functie a onz-pers:ZorgverlenerFunctie }
59
60          # Geldig op eerste dag van het kwartaal (noemer)
61          BIND( IF(?start_afspraak <= ?p_start && (!BOUND(?eind_afspraak) || ?eind_afspraak >= ?p_start), 1, 0) AS ?op_peildatum_eerder )
62
63          # Geldig op eerste dag van het volgende kwartaal (voor UITSTROOM moet dit 0 worden)
64          BIND( IF(?start_afspraak <= ?p_next  && (!BOUND(?eind_afspraak) || ?eind_afspraak >= ?p_next ), 1, 0) AS ?op_peildatum_later )
65        }
66        GROUP BY ?Periode ?werknemer
67      }
68    }
69    GROUP BY ?Periode 
70  }
71}
72ORDER BY ?Periode